default.pp

# @summary Install and configure Démarches Simplifiées
#
# Install and configure Démarches Simplifiées, the open source tool for french administration to simply create form
#
# @param _system_username
# Name of the system user for DémarchesSimplifiées
# @param db_user_name
# Name of the Postgres user for the database ds
# @param db_user_password
# Password for DS database Password for the Postgres user ds
# @param _ds_home
# Path for the home directory of the system user ds
# @param db_name
# Name of the database for DémarchesSimplifiées
# @param _ds_db_role
# Postgres role of user and databade for DémarchesSimplifiées
# @param db_host
# Hostname of Postgres relay host
# @param db_port
# Port of Postgres relay host
# @param db_test_name
# Name of the test database
# @param db_test_user_name
# Name of the test database's user
# @param db_test_user_password
# Password of the test database's user
# @param _ds_db_test_role
# Role for the test database
# @param source_code_of_ds
# Repository to download Démarches Simplifiées
# @param preRequistes
# List of packages to be installed beforehand

# #############################################################################
# Variables

# System user for Démarches Simplifiées
$_system_username = 'vagrant'
$_ds_home = "/home/${_system_username}"
$_ds_project_directory = "$_ds_home/demarches-simplifiees.fr"
$db_user_name = 'ds'
$db_name = 'ds'
$_ds_db_role = 'ds'
$db_user_password = 'kiki34' # /!\ Do not forget to change this passwd in production :)
$db_host = 'localhost'
$db_port = 3434
$db_test_name = 'tps_test'
$db_test_user_name = 'tps_test'
$db_test_user_password = 'tps_test'
$_ds_db_test_role = 'test'
#$source_code_of_ds = 'https://github.com/betagouv/demarches-simplifiees.fr.git'
$local_source_code_of_ds = '/shared_dev/'
$_path_bundle = "$_ds_home/rbenv/shims/"
$db_database = 'ds'
$db_pool = ''

# #############################################################################
# System user for Démarches Simplifiées app
accounts::user { $_system_username:
}

# #############################################################################
# PREREQUISITES Postgres
# Install all global package required
$preRequistes = [
  'curl',
  'autoconf',
  'bison',
  'chromium-browser',
  'chromium-chromedriver',
  'libcurl4-openssl-dev',
  'libpq-dev',
]

package { $preRequistes:
  ensure  => 'installed',
  require => Class['apt::update'],
}

# Create a soft link on /shared_dev directory which is a share folder of your local project.
# Comment this part if you want to clone a repository installation.
file { $_ds_project_directory:
  ensure => link,
  target => "$local_source_code_of_ds",
}

# Desactivation of IPv6
sysctl { 'net.ipv6.conf.all.autoconf':
  ensure => present,
  value  => '1',
}

# #############################################################################
# PREREQUISITES Create and customize values of DB in .env
# Copy the file `config/env.example`, rename it to `.env` and put it at the root of the project as 'ds' user
# NOTE: once this code is transformed in a clear Puppet Module, all the file_lines should be treated with
#       content => epp()
file { "$_ds_project_directory/.env":
  ensure  => present,
  source  => "$_ds_project_directory/config/env.example",
  # content => epp('vagrant-demarches-simplifiees/env.epp'),
  owner   => $_system_username,
  require => File[$_ds_project_directory],
}

# As long as this is not a pupet module, we don't use a template but 'file_line'.
# Puppuet module should use a template to set proper values.
# Set values for Database and Github Oauth token in config file '.env'
file_line { 'DB_DATABASE':
  ensure  => present,
  path    => "$_ds_project_directory/.env",
  line    => "DB_DATABASE=\"$db_name\"",
  match   => '^DB_DATABASE="tps_development"',
  require => File["$_ds_project_directory/.env"],
}
file_line { 'DB_USERNAME':
  ensure  => present,
  path    => "$_ds_project_directory/.env",
  line    => "DB_USERNAME=\"$db_user_name\"",
  match   => '^DB_USERNAME="tps_development"',
  require => File["$_ds_project_directory/.env"],
}
file_line { 'DB_PASSWORD':
  ensure  => present,
  path    => "$_ds_project_directory/.env",
  line    => "DB_PASSWORD=\"$db_user_password\"",
  match   => '^DB_PASSWORD="tps_development"',
  require => File["$_ds_project_directory/.env"],
}

# Modification of bin/setup file.
# As we already created the DB we don't need to recreate it.
file_line { 'db:setup':
  ensure  => present,
  path    => "$_ds_project_directory/bin/setup",
  line    => "  system! 'bin/rails db:schema:load db:seed'",
  match   => "  system! 'bin/rails db:setup'",
  require => File[$_ds_project_directory],
}

# #############################################################################
# PREREQUISITES ruby
# Install rbenv
class { 'rbenv':
  install_dir => "$_ds_home/rbenv",
  owner       => $_system_username,
}
rbenv::plugin { 'rbenv/ruby-build': }
-> rbenv::build { '2.6.5': global => true }

# Ensure permissions on /usr/bin/env
-> file { '/usr/bin/env':
  ensure => file,
  owner  => "$_system_username",
}

# #############################################################################
# PREREQUISITES Postgres
# This ensures a PostgreSQL server is installed
class { 'postgresql::server': }

# Grant membership to a role
postgresql::server::role { $_ds_db_role:
  password_hash => postgresql_password($db_user_name, $db_user_password),
}
# Create a role, database and assign the correct permissions
-> postgresql::server::db { $db_name:
  user     => $db_user_name,
  password => postgresql_password($db_user_name, $db_user_password),
  owner    => $_ds_db_role,
}

# Role Test creation
postgresql::server::role { $_ds_db_test_role:
  password_hash => postgresql_password($db_test_user_name, $db_test_user_password),
}
# DB Test + Test Postgres user creation + assignation permissions
-> postgresql::server::db { $db_test_name:
  user     => $db_test_user_name,
  password => postgresql_password($db_test_user_name, $db_test_user_password),
  owner    => $_ds_db_test_role,
}

# Activate an extension 'unaccent' on postgresql databases (both ds and tps_test)
[$db_test_name, $db_name].each | $database | {
  postgresql::server::extension { "unaccent-${database}":
    database  => $database,
    extension => 'unaccent',
    ensure    => present,
  }
}

# PGPASS file
$_pgpass_content = "
# hostname:port:database:username:password
${db_host}:${db_port}:${db_name}:${db_user_name}:${db_user_password}
${db_host}:${db_port}:${db_test_name}:${db_test_user_name}:${db_test_user_password}
"

file { 'PGPASS file':
  ensure  => file,
  path    => "${_ds_home}/.pgpass",
  mode    => '0600',
  owner   => $_system_username,
  content => $_pgpass_content,
}

# #############################################################################
# PREREQUISITES nodejs
# The desired version must be specified.
class { 'nodejs':
  repo_url_suffix => '12.x',
}

# #############################################################################
# PREREQUISITES Yarn
# Install Yarn
# /!\ By default, last version is installed
class { 'yarn': }

# #############################################################################
# PREREQUISITES tmux
# Install tmux
class { 'tmux': }